// Qt
import QtQuick 2.15

// Project
//  Qml imports
import "qrc:/globals"

ProcessStatusView { id: _root
    property bool isDialog: false

    title               : _root.isDialog ? qsTr("Disconnect Dry Bicarbonate Cartridge") : qsTr("Bicarb Cartridge Options")
    leftButtonText      : vTreatmentDryBicartDisconnect.drainInProgress ? qsTr("Cancel") : qsTr("Drain")
    centerButtonText    : qsTr("Depressurize")
    rightButtonText     : isDialog ? qsTr("Done") : ""
    leftButtonEnabled   : ! vTreatmentDryBicartDisconnect.depressurizeInProgress
    centerButtonEnabled : ! vTreatmentDryBicartDisconnect.drainInProgress
    rightButtonEnabled  : ! vTreatmentDryBicartDisconnect.depressurizeInProgress && ! vTreatmentDryBicartDisconnect.drainInProgress

    progressText        :   vTreatmentDryBicartDisconnect.drainInProgress           ? qsTr("Draining Bicart...")    :
                            vTreatmentDryBicartDisconnect.depressurizeInProgress    ? qsTr("Depressurizing...")     :
                            vTreatmentDryBicartDisconnect.progress >= vTreatmentDryBicartDisconnect.total &&
                            vTreatmentDryBicartDisconnect.total > 0                 ? qsTr("Complete")              : ""


    minimum             : 0
    maximum             : vTreatmentDryBicartDisconnect.total
    value               : vTreatmentDryBicartDisconnect.progress

    onLeftPressed       : vTreatmentDryBicartDisconnect.drainInProgress ? vTreatmentAdjustmentDryBicartDisconnect.doCancel() :
                                                                          vTreatmentAdjustmentDryBicartDisconnect.doDrain()
    onCenterPressed     : vTreatmentAdjustmentDryBicartDisconnect.doDepressurize()
    onRightPressed      : vTreatmentAdjustmentDryBicartDisconnect.doDone()


    Text { id: _additionalDescription
        anchors {
            top             : _root.top
            topMargin       : Variables.defaultMargin * 4
            horizontalCenter: parent.horizontalCenter
        }
        visible         : _root.isDialog
        color           : Colors.offWhite
        font.pixelSize  : Fonts.fontPixelTextRectExtra
        font.weight     : Font.Medium
        text            : qsTr("Disconnect your consumables per your clinic's instructions")
    }


}