/*!
 *
 * Copyright (c) 2021-2024 Diality Inc. - All Rights Reserved.
 * \copyright
 * THIS CODE MAY NOT BE COPIED OR REPRODUCED IN ANY FORM, IN PART OR IN
 * WHOLE, WITHOUT THE EXPLICIT PERMISSION OF THE COPYRIGHT OWNER.
 *
 * \file    EndTreatmentRinsebackComplete.qml
 * \author  (last)      msuleiman
 * \date    (last)      30-Jun-2023
 * \author  (original)  Behrouz NematiPour
 * \date    (original)  11-Apr-2021
 *
 */

// Qt
import QtQuick 2.12

//  Qml imports
import "qrc:/globals"
import "qrc:/components"
import "qrc:/pages/endtreatment"

/*!
 * \brief   the end treatment rinseback complete screen
 */
EndTreatmentBase { id: _root
    objectName: "_EndTreatmentRinsebackComplete"

    signal additionalClicked    ()
    signal treatmentBackClicked ()
    signal treatmentEndClicked  ()

    title.text              : qsTr("Rinseback Complete")
    instructionBased        : true
    header.confirmVisible   : false

    header.backEnabled      : true
    header.backVisible      : vTreatmentTime        .time_IsLeft
    onBackClicked           : treatmentBackClicked()

    hasTimeout              : vTreatmentRinseback   .timeoutTotal
    timeoutValue            : vTreatmentRinseback   .timeoutCountDown * 60

    footer {
        width       : parent.width
        height      : Variables.touchRectHeight
    }

    FooterStatic {
        childrenWidth   : 300
        anchors.fill    : footer
        children        : [

            TouchRect { id : _endTreatmentTouchRect
                visible         : true // after the rinseback complete user can always end the treatment, regardless of incomplete or compeleted treatment
                text.text       : qsTr("END TREATMENT")
                isDefault       : ! vTreatmentTime  .time_IsLeft
                onClicked       : treatmentEndClicked()
            },

            TouchRect { id : _recirculateTouchRect
                visible         : vTreatmentTime        .time_IsLeft
                enabled         : vTreatmentRinseback   .isCompleted      && _root.instructionIsLast
                text.text       : qsTr("RECIRCULATE")
                onClicked       : confirmClicked()
            },

            TouchRect { id : _beginRinsebackTouchRect
                visible         : true
                text.text       : qsTr("SALINE BOLUS")
                onClicked       : additionalClicked()

                Text { id: _salineVolumeLabel
                    anchors.left        : _beginRinsebackTouchRect.text.right
                    anchors.bottom      : _beginRinsebackTouchRect.text.top
                    anchors.leftMargin  : 5
                    text                : qsTr("(50mL)")
                    font.pixelSize      : Fonts.fontPixelFluidVolume
                    color               : _beginRinsebackTouchRect.text.color
                }
            }
        ]
    }
}