/*!
 *
 * Copyright (c) 2020-2024 Diality Inc. - All Rights Reserved.
 * \copyright
 * THIS CODE MAY NOT BE COPIED OR REPRODUCED IN ANY FORM, IN PART OR IN
 * WHOLE, WITHOUT THE EXPLICIT PERMISSION OF THE COPYRIGHT OWNER.
 *
 * \file    TreatmentAdjustmentUltrafiltrationPaused.qml
 * \author  (last)      Vy
 * \date    (last)      16-Mar-2023
 * \author  (original)  Behrouz NematiPour
 * \date    (original)  14-May-2020
 *
 */

// Qt
import QtQuick 2.12

// Project

//  Qml imports
import "qrc:/globals"
import "qrc:/components"

/*!
 * \brief   TreatmentAdjustmentUltrafiltrationStart.qml is the screen
 *          To adjust the treatment ultrafiltration
 */
TreatmentAdjustmentBase { id: _root
    contentItem.objectName: "TreatmentAdjustmentUltrafiltrationPaused"  //SquishQt testability
    QtObject { id: _private
        property real minimum: vTreatmentUltrafiltration.minimum
        property real maximum: vTreatmentUltrafiltration.maximum
        property real value  : vTreatmentUltrafiltration.ultrafiltration_RefUFVol
    }

    signal   editClicked()
    signal resumeClicked()

    confirmVisible  : false

    information {
        visible     : true && information.text && ! notification.visible
        imageSource : ufInfoImageSource
        text        : ufInfoText
    }

    titleText   : qsTr("ULTRAFILTRATION VOLUME") + "   " + Variables.unitTextUltrafiltrationVolume

    ProgressBarEx { id: _progressbarex
        width   : Variables.ultrafiltrationProgressbarWidth
        height  : Variables.ultraFiltrationProgressBarHeight
        anchors {
            top: parent.top
            topMargin: 250
            horizontalCenter: parent.horizontalCenter
        }
        decimal : Variables.ultrafiltrationPrecision
        minimum : _private.minimum
        maximum : _private.maximum
        value   : _private.value
        valueEx : 0
    }

    TouchRect { id: _editButton
        width: 530
        height: 95
        anchors {
            top: parent.top
            topMargin: 350
            horizontalCenter: parent.horizontalCenter
        }
        isDefault: true
        text  {
            text: qsTr("EDIT ULTRAFILTRATION VOLUME")
            font.weight: Font.DemiBold
            font.pixelSize: 26 //Fonts.fontPixelBack
        }
        onClicked: editClicked()
    }

    TouchRect { id: _resumeButton
        visible: isUFPaused
        width: 530
        height: 95
        anchors {
            top: _editButton.bottom
            topMargin: 20
            horizontalCenter: parent.horizontalCenter
        }

        Image { id: _image
            anchors {
                verticalCenter: _resumeButton.verticalCenter
                left          : _resumeButton.left
                leftMargin    : 50
            }

            width : Variables.pauseIconDiameter
            height: Variables.pauseIconDiameter
            source: "qrc:/images/iResume"
        }

        text  {
            text: qsTr("RESUME ULTRAFILTRATION")
            font.weight: Font.DemiBold
            font.pixelSize: 26 //Fonts.fontPixelBack
            anchors {
                centerIn: null // disable the parent anchor
                verticalCenter: _resumeButton.verticalCenter
                left: _image.right
                leftMargin: 25
            }
        }
        onClicked: resumeClicked()
    }
}