/*!
 *
 * Copyright (c) 2020-2024 Diality Inc. - All Rights Reserved.
 * \copyright
 * THIS CODE MAY NOT BE COPIED OR REPRODUCED IN ANY FORM, IN PART OR IN
 * WHOLE, WITHOUT THE EXPLICIT PERMISSION OF THE COPYRIGHT OWNER.
 *
 * \file    TreatmentUltrafiltration.qml
 * \author  (last)      Behrouz NematiPour
 * \date    (last)      26-Sep-2023
 * \author  (original)  Behrouz NematiPour
 * \date    (original)  27-Jan-2020
 *
 */

// Qt
import QtQuick 2.12

// Project

//  Qml imports
import "qrc:/globals"
import "qrc:/components"

/*!
 * \brief   Treatment Screen Ultrafiltration section
 */
TouchArea { id: _root
    readonly property real minimum  : vTreatmentUltrafiltration.minimum
    readonly property real maximum  : vTreatmentUltrafiltration.maximum
    readonly property real value    : vTreatmentUltrafiltration.ultrafiltration_RefUFVol

    clip    : false

    x       : 0
    y       : 0
    width   : 200
    height  : 200

    isTouchable : ! isSBInProgress
    title   : qsTr("ULTRAFILTRATION VOLUME") + " " + Variables.unitTextUltrafiltrationVolume
    notification {
        visible     : true
        text        : ufInfoText
        textColor   : ufInfoTextColor
    }

    Text { id: _ufCurrentRateText
        anchors  {
            right: parent.right
            rightMargin: Variables.arrowWidth * 2 // Aligning text to be beyond the arrow
            top: parent.top
        }
        horizontalAlignment : Text.AlignRight
        verticalAlignment   : Text.AlignVCenter
        height              : Variables.arrowHeight

        text: qsTr("(%1 %2)").arg(vTreatmentUltrafiltration.ultrafiltration_UfCurrentRate.toFixed(0))
                             .arg(Variables.unitTextUltrafiltrationRate                             )
        font.pixelSize: Fonts.fontPixelUltrafiltrationRateUnit
        color: Colors.touchTextAreaTitle
    }

    ProgressBarEx { id: _progressbarex
        enabled : _root.isTouchable
        y       : 75
        width   : parent.width
        height  : Variables.ultraFiltrationProgressBarHeight

        onClicked           : _root.clicked()
        onProgressClicked   : _root.clicked()
        onExtraClicked      : _root.clicked()

        decimal : Variables.ultrafiltrationPrecision
        minimum : _root.minimum
        maximum : _root.maximum
        value   : _root.value
        valueEx : 0

        marker.color : isUFPaused ? "dimgray" : Colors.rangeMarker
    }
}